Art in the style of Vera Molnár

Kicsit ássunk a Sinclair gépek grafikai lehetőségeinek a mélyére...
Avatar
Bali
Alapító tag
Hozzászólások: 2538
Csatlakozott: 2012.01.06. 12:34
Tartózkodási hely: Budapest III.
Kapcsolat:

Art in the style of Vera Molnár

Hozzászólás Szerző: Bali »

A BASIC on the ZX Spectrum Fb csoportban leltem, valaki ihletet merített Molnár Vera munkáiból. Vajon ki is lehetett Ő?

Kód: Egész kijelölése

10 BRIGHT 0: INK 0: PAPER 5: BORDER 5: CLS
20 LET s=1: FOR a=0 TO 7:
POKE USR "A"+a,s:
POKE USR "B"+7-a,s:
POKE USR "C"+a,16:
POKE USR "D"+a,255 AND a=4:
LET s=s+s: NEXT a
30 FOR s=2 TO 1 STEP -1: FOR y=0 TO 1+(20 AND s=2)
40 PRINT #s;AT y,0;: FOR x=0 TO 23:
PRINT #s; BRIGHT 1; PAPER 7;CHR$ (144+INT (4*RND));:
NEXT x
50 NEXT y: NEXT s
60 LET s$="The_ArtStyle__of_____Vera___Molnar_"
70 PAPER 7: FOR y=0 TO 4:
PRINT AT 17+y,25;s$(1+y*7 TO 7+y*7):
NEXT y
80 PAUSE 0: GO TO 10
veramolnar_1.jpg
quatre_elements_distribues_au_hasard.pdf
(320.38 KiB) Letöltve 13 alkalommal.
-= Bali =-
(c) 1983-2017 Evil-Soft
Avatar
Bali
Alapító tag
Hozzászólások: 2538
Csatlakozott: 2012.01.06. 12:34
Tartózkodási hely: Budapest III.
Kapcsolat:

Re: Art in the style of Vera Molnár

Hozzászólás Szerző: Bali »

Még egy gyöngyszem, melyet 1984-es Hommage á Dürer inspirált:

Kód: Egész kijelölése

10 GO SUB 270
20 PAPER 5: BRIGHT 0: BORDER 5: CLS
30 PRINT #1;AT 0,0; PAPER 5; BRIGHT 1;TAB 6;"Inspired by image02",'"Hommage á Dürer,Vera Molnár,1984"
40 INK 0: PAPER 7: BRIGHT 1: FOR i=0 TO 21: PRINT AT i,5;TAB 27: NEXT i
50 LET n=14: LET d=4
60 DIM x(16): DIM y(16)
70 DIM p(n): FOR i=1 TO n: LET p(i)=i: NEXT i
80 FOR j=0 TO 3: FOR i=0 TO 3: LET k=4*j+i+1: LET x(k)=i*d: LET y(k)=j*d: NEXT i: NEXT j
90 INK 0
100 FOR y=157 TO 5 STEP -19
110 FOR x=45 TO 197 STEP 19
120 GO SUB 210
130 PLOT x+x(p(1)),y+y(p(1))
140 FOR i=2 TO n
150 LET a=p(i-1): LET b=p(i)
160 DRAW x(b)-x(a),y(b)-y(a)
170 NEXT i
180 NEXT x
190 NEXT y: PAUSE 0: GO TO 20
200 PRINT 256*PEEK 23606

210 REM shuffle
220 FOR j=1 TO 8
230 LET a=INT (n*RND)+1
240 LET b=INT (n*RND)+1: IF a=b THEN GO TO 240
250 LET t=p(a): LET p(a)=p(b): LET p(b)=t
260 NEXT j: RETURN

270 FOR i=USR "A" TO USR "C"+7: READ k: POKE i,k: NEXT i: RETURN
280 DATA 32,16,56,4,60,68,60,0,68,0,68,68,68,68,56,0, 8,16,56,4,60,68,60,0
veramolnar_2.jpg
-= Bali =-
(c) 1983-2017 Evil-Soft
Avatar
Bali
Alapító tag
Hozzászólások: 2538
Csatlakozott: 2012.01.06. 12:34
Tartózkodási hely: Budapest III.
Kapcsolat:

Re: Art in the style of Vera Molnár

Hozzászólás Szerző: Bali »

Világhírű magyar festőnő, aki először készített számítógéppel képeket.

Vera Molnar
-= Bali =-
(c) 1983-2017 Evil-Soft
csaba
Alapító tag
Hozzászólások: 363
Csatlakozott: 2012.01.09. 18:18
Rádióamatőr hívójel: HG5BMU
Tartózkodási hely: Surány
Kapcsolat:

Re: Art in the style of Vera Molnár

Hozzászólás Szerző: csaba »

Nekem csak egy "hamisítványom" van,
jó lenne rájönni hogyan lehetne egy "eredeti".

vera.JPG
Avatar
Bali
Alapító tag
Hozzászólások: 2538
Csatlakozott: 2012.01.06. 12:34
Tartózkodási hely: Budapest III.
Kapcsolat:

Re: Art in the style of Vera Molnár

Hozzászólás Szerző: Bali »

Adaléokok.

Korai plotter rajzok (1968)
1968-ban Molnár Vera számítógéppel kezdett dolgozni a Sorbonne-i kísérleti pszichológiai laboratóriumban, ahol elkészítette első plotterrajzait, amikkel gép használata nélkül kísérletezett a korábbi években.

Kat-2.jpg
Forrás
-= Bali =-
(c) 1983-2017 Evil-Soft
Avatar
Bali
Alapító tag
Hozzászólások: 2538
Csatlakozott: 2012.01.06. 12:34
Tartózkodási hely: Budapest III.
Kapcsolat:

Re: Art in the style of Vera Molnár

Hozzászólás Szerző: Bali »

Itt egy újabb implementáció, melyet a Lent mouvement giratoire,1957 c. műve inspirált.

A programokat innen lopom, az elkövető Uwe Geiken.

Kód: Egész kijelölése

10 REM V. Molnar,Lent mouvement giratoire,1957
20 PAPER 5: BRIGHT 0: BORDER 5: CLS 
30 PAPER 7: INK 2: BRIGHT 1: FOR i=0 TO 21: 
PRINT AT i,5;TAB 27: NEXT i
40 LET n=29: LET m=6: LET d=INT (176/n): 
LET r=d-1: LET v=d/2: LET u=40+v
50 DIM c(m): DIM s(m): FOR i=1 TO m: 
LET p=PI*(i-1)/m: LET c(i)=r*COS p: LET s(i)=r*SIN p: NEXT i
60 LET k=INT (m*RND)+1
70 FOR j=0 TO n-1: FOR i=0 TO n-1
80 LET x=c(k): LET y=s(k)
90 PLOT u+i*d-x/2,v+j*d-y/2
100 DRAW x,y
110 LET k=INT (m*RND)+1
120 NEXT i: NEXT j
130 BRIGHT 0: PRINT #1;AT 0,0; PAPER 7;"Variation of Vera Molnars",'"Lent mouvement giratoire, 1957",
140 PAUSE 0: RUN
Érdemes lehet játszani az n és m paraméterekkel.
VM_LentMovement57.jpg
lent_mouvement_giratoire.pdf
(330.04 KiB) Letöltve 20 alkalommal.
-= Bali =-
(c) 1983-2017 Evil-Soft
Válasz küldése

Vissza: “Grafika”