Oldal: 1 / 1

8 INK szín, 32 PAPER szín BASIC-ből

Elküldve: 2019.04.19. 13:56
Szerző: Bali
Nagy Dani követte el az alábbi kis BASIC szín demót, okulásul mellékelem.

Kód: Egész kijelölése

1 DATA 0,3,28,31,224,227,252,255
2 DATA "BLACK","BLUE","RED","MAGENTA","GREEN","CYAN","YELLOW","WHITE"
10 FOR p=0 TO 31
20 LET r=11-ABS (p-10): LET r=r*(r>0): IF r>7 THEN LET r=7
30 LET g=11-ABS (p-17): LET g=g*(g>0): IF g>7 THEN LET g=7
40 LET b=11-ABS (p-25): LET b=b*(b>0): IF b>7 THEN LET b=7
50 LET s=7-ABS (p-31): LET s=s*(s>0)
60 LET r=r+s: LET b=INT (b/2)
70 LET c=INT (p/8): LET j=p-8*c
80 OUT 48955,c*16+8+j
90 OUT 65339,g*32+r*4+b
95 FOR k=0 TO 21: POKE 22528+k*32+p,p*8: NEXT k
100 NEXT p
110 FOR c=0 TO 3: RESTORE : FOR i=0 TO 7: READ a
120 OUT 48955,c*16+i
130 OUT 65339,a
140 NEXT i: NEXT c
150 OUT 48955,64: OUT 65339,1
160 PAPER 8: BRIGHT 8: FLASH 8
170 FOR i=0 TO 7: INK i: READ a$: PRINT AT i*2+3,0;a$;TAB 16-.5*LEN a$;a$;TAB 32-LEN a$;a$;
180 FOR y=0 TO 3: PLOT 0,143-16*i-y: DRAW 255,0: NEXT y: NEXT i
190 PAUSE 0

Re: 8 INK szín, 32 PAPER szín BASIC-ből

Elküldve: 2019.04.19. 14:00
Szerző: Bali
8INK32PAPER.png

Re: 8 INK szín, 32 PAPER szín BASIC-ből

Elküldve: 2019.04.23. 07:24
Szerző: csaba
Érdekes, nézegetve a tesztképet, nem tudom az összes szín szerepel-e rajta, de mintha a green-nek és a magentának nem lenne azonos ink-paper árnyalata.
De lehet, hogy a tömörítés miatt látszik így.